''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''
' Script        : ADODB Datenbankzugriff                                       '
' File          : 09_01_ADODB_DBZugriff.vbs                                    '
' Date          : 2007-06-27 - Last modified: 2007-06-27                       '
'                                                                              '
'               Michael Puff - http://www.michael-puff.de                      '
'                                                                              '
'          Auslesen einer Datenbank und schreiben in eine Textdatei.           '
'                                                                              '
''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''

Option Explicit

const CAPTION = "09_01_ADODB_DBZugriff.vbs"
const DONE = "Die Datensätze wurden in die Textdatei geschrieben."
const CONSTR = "driver=MySQL ODBC 3.51 Driver;server=10.17.171.200;uid=root;pwd=;database=Flugbetrieb;option=NUM"
const SQLStatement = "SELECT * FROM flugplan"
const Filename = "c:\mp_work\test.txt"

' DB Variablen
dim AdoDataCon
dim rs
' TextStream variablen
dim fso
dim ts

private sub WriteRecToFile(rs, ts)
dim s
  s = rs.fields.item("FlugNr")
  s = s & " " & rs.fields.item("Ziel")
  ' Testausgabe
  MsgBox s, 0, Caption
  ' Zeile schreiben
  ts.WriteLine(s)  
end sub

Set AdoDataCon = CreateObject("ADODB.Connection")

' Datenbankverbindung aufbauen
AdoDataCon.Open(CONSTR)
' SQL Statement
Set rs = AdoDataCon.Execute(SQLStatement)

' Textstream Objekt erstellen
Set fso = CreateObject("Scripting.FilesystemObject")
Set ts = fso.CreateTextFile(Filename)

while rs.eof = False
  WriteRecToFile rs, ts
  rs.MoveNext
wend

' Aufräumen
rs.Close
AdoDataCon.Close
ts.Close

MsgBox DONE, 0, CAPTION